
Zusammenfassung
VLOOKUP ist eine Excel-Funktion zum Nachschlagen von Daten in einer vertikal organisierten Tabelle. VLOOKUP unterstützt ungefähre und genaue Übereinstimmungen sowie Platzhalter (*?) Für Teilübereinstimmungen. Suchwerte müssen in der ersten Spalte der an VLOOKUP übergebenen Tabelle erscheinen.
Zweck
Suchen Sie einen Wert in einer Tabelle, indem Sie ihn in der ersten Spalte abgleichenRückgabewert
Der übereinstimmende Wert aus einer Tabelle.Syntax
= VLOOKUP (Wert, Tabelle, col_index, (range_lookup))Argumente
- value - Der Wert, nach dem in der ersten Spalte einer Tabelle gesucht werden soll.
- Tabelle - Die Tabelle, aus der ein Wert abgerufen werden soll.
- col_index - Die Spalte in der Tabelle, aus der ein Wert abgerufen werden soll.
- range_lookup - (optional) TRUE = ungefähre Übereinstimmung (Standard). FALSE = genaue Übereinstimmung.
Ausführung
Excel 2003Verwendungshinweise
VLOOKUP ist eine Excel-Funktion zum Abrufen von Daten aus einer vertikal organisierten Tabelle. Suchwerte müssen in der ersten Spalte der an VLOOKUP übergebenen Tabelle erscheinen. VLOOKUP unterstützt ungefähre und genaue Übereinstimmungen sowie Platzhalter (*?) Für Teilübereinstimmungen.
Vertikale Daten | Spaltennummern | Sieht nur richtig aus | Passende Modi | Genaue Übereinstimmung | Ungefähre Übereinstimmung | Erstes Spiel | Wildcard Match | Zwei-Wege-Suche | Mehrere Kriterien | # N / A Fehler | Videos
V ist für vertikal
Der Zweck von VLOOKUP besteht darin, Informationen aus einer Tabelle zu erhalten, die wie folgt organisiert ist:
Mit der Bestellnummer in Spalte B als Nachschlagewert kann VLOOKUP die Kunden-ID, den Betrag, den Namen und den Status für jede Bestellung abrufen. Um beispielsweise den Kundennamen für die Bestellung 1004 zu erhalten, lautet die Formel:
=VLOOKUP(1004,B5:F9,4,FALSE) // returns "Sue Martin"
Für horizontale Daten können Sie HLOOKUP, INDEX und MATCH oder XLOOKUP verwenden.
VLOOKUP basiert auf Spaltennummern
Wenn Sie VLOOKUP verwenden, stellen Sie sich vor, dass jede Spalte in der Tabelle beginnend von links nummeriert ist. Geben Sie die entsprechende Nummer als "Spaltenindex" an, um einen Wert aus einer bestimmten Spalte abzurufen. Der Spaltenindex zum Abrufen des folgenden Vornamens lautet beispielsweise 2:
Der Nachname und die E-Mail können mit den Spalten 3 und 4 abgerufen werden:
=VLOOKUP(H3,B4:E13,2,FALSE) // first name =VLOOKUP(H3,B4:E13,3,FALSE) // last name =VLOOKUP(H3,B4:E13,4,FALSE) // email address
VLOOKUP sieht nur richtig aus
VLOOKUP kann nur nach rechts schauen. Die Daten, die Sie abrufen möchten (Ergebniswerte), können in einer beliebigen Spalte rechts neben den Suchwerten angezeigt werden:
Wenn Sie links nach Werten suchen müssen, lesen Sie INDEX und MATCH oder XLOOKUP.
Genaue und ungefähre Übereinstimmung
VLOOKUP verfügt über zwei Übereinstimmungsmodi: exakt und ungefähr. Der Name des Arguments, das den Abgleich steuert, lautet " range_lookup ". Dies ist ein verwirrender Name, da er etwas mit Zellbereichen wie A1: A10 zu tun zu haben scheint. Tatsächlich bezieht sich das Wort "Bereich" in diesem Fall auf "Wertebereich". Wenn range_lookup TRUE ist, stimmt VLOOKUP eher mit einem Wertebereich als mit einem exakten Wert überein. Ein gutes Beispiel hierfür ist die Verwendung von VLOOKUP zur Berechnung von Noten.
Es ist wichtig zu verstehen, dass range_lookup standardmäßig TRUE ist. Dies bedeutet , dass VLOOKUP standardmäßig eine ungefähre Übereinstimmung verwendet, was gefährlich sein kann. Setzen Sie range_lookup auf FALSE, um eine genaue Übereinstimmung zu erzwingen:
=VLOOKUP(value, table, col_index) // approximate match (default) =VLOOKUP(value, table, col_index, TRUE) // approximate match =VLOOKUP(value, table, col_index, FALSE) // exact match
Hinweis: Sie können für eine genaue Übereinstimmung auch Null (0) anstelle von FALSE angeben.
Genaue Übereinstimmung
In den meisten Fällen möchten Sie VLOOKUP wahrscheinlich im Modus für exakte Übereinstimmungen verwenden. Dies ist sinnvoll, wenn Sie einen eindeutigen Schlüssel als Suchwert verwenden können, z. B. den Filmtitel in diesen Daten:
Die Formel in H6 zum Finden des Jahres , basierend auf einer genauen Übereinstimmung des Filmtitels, lautet:
=VLOOKUP(H4,B5:E9,2,FALSE) // FALSE = exact match
Ungefähre Übereinstimmung
In cases when you want the best match , not necessarily an exact match , you'll want to use approximate mode. For example, below we want to look up a commission rate in the table G5:H10. The lookup values come from column C. In this example, we need to use VLOOKUP in approximate match mode, because in most cases an exact match will never be found. The VLOOKUP formula in D5 is configured to perform an approximate match by setting the last argument to TRUE:
=VLOOKUP(C5,$G$5:$H$10,2,TRUE) // TRUE = approximate match
VLOOKUP will scan values in column G for the lookup value. If an exact match is found, VLOOKUP will use it. If not, VLOOKUP will "step back" and match the previous row.
Note: data must be sorted in ascending order by lookup value when you use approximate match mode with VLOOKUP.
First match
In the case of duplicate values, VLOOKUP will find the first match when the match mode is exact. In screen below, VLOOKUP is configured to find the price for the color "Green". There are three entries with the color Green, and VLOOKUP returns the price for the first entry, $17. The formula in cell F5 is:
=VLOOKUP(E5,B5:C11,2,FALSE) // returns 17
Wildcard match
The VLOOKUP function supports wildcards, which makes it possible to perform a partial match on a lookup value. For instance, you can use VLOOKUP to retrieve values from a table after typing in only part of a lookup value. To use wildcards with VLOOKUP, you must specify exact match mode by providing FALSE or 0 for the last argument, range_lookup . The formula in H7 retrieves the first name, "Michael", after typing "Aya" into cell H4:
=VLOOKUP($H$4&"*",$B$5:$E$104,2,FALSE)
Read a more detailed explanation here.
Two-way lookup
Inside the VLOOKUP function, the column index argument is normally hard-coded as a static number. However, you can also create a dynamic column index by using the MATCH function to locate the right column. This technique allows you to create a dynamic two-way lookup, matching on both rows and columns. In the screen below, VLOOKUP is configured to perform a lookup based on Name and Month. The formula in H6 is:
=VLOOKUP(H4,B5:E13,MATCH(H5,B4:E4,0),0)
For more details, see this example.
Note: In general, INDEX and MATCH is a more flexible way to perform two-way lookups.
Multiple criteria
The VLOOKUP function does not handle multiple criteria natively. However, you can use a helper column to join multiple fields together, and use these fields like multiple criteria inside VLOOKUP. In the example below, Column B is a helper column that concatenates first and last names together with this formula:
=C5&D5 // helper column
VLOOKUP is configured to do the the same thing to create a lookup value. The formula in H6 is:
=VLOOKUP(H4&H5,B5:E13,4,0)
For details, see this example.
Note: INDEX and MATCH and XLOOKUP are more robust ways to handle lookups based on multiple criteria.
VLOOKUP and #N/A errors
If you use VLOOKUP you will inevitably run into the #N/A error. The #N/A error just means "not found". For example, in the screen below, the lookup value "Toy Story 2" does not exist in the lookup table, and all three VLOOKUP formulas return #N/A:
One way to "trap" the NA error is to use the IFNA function like this:
The formula in H6 is:
=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"Not found")
The message can be customized as desired. To return nothing (i.e. to display a blank result) when VLOOKUP returns #N/A you can use an empty string like this:
=IFNA(VLOOKUP(H4,B5:E9,2,FALSE),"") // no message
The #N/A error is useful because it tells you something is wrong. In practice, there are many reasons why you might see this error, including:
- The lookup value does not exist in the table
- The lookup value is misspelled, or contains extra space
- Match mode is exact, but should be approximate
- The table range is not entered correctly
- You are copying VLOOKUP, and the table reference is not locked
Read more: VLOOKUP without #N/A errors
More about VLOOKUP
- More VLOOKUP examples
- VLOOKUP videos
- 23 tips for using VLOOKUP
Other notes
- Range_lookup controls whether value needs to match exactly or not. The default is TRUE = allow non-exact match.
- Set range_lookup to FALSE to require an exact match and TRUE to allow a non-exact match .
- If range_lookup is TRUE (the default setting), a non-exact match will cause the VLOOKUP function to match the nearest value in the table that is still less than value .
- When range_lookup is omitted, the VLOOKUP function will allow a non-exact match, but it will use an exact match if one exists.
- If range_lookup is TRUE (the default setting) make sure that lookup values in the first row of the table are sorted in ascending order. Otherwise, VLOOKUP may return an incorrect or unexpected value.
- If range_lookup is FALSE (require exact match), values in the first column of table do not need to be sorted.
Related videos





