Generische Formel
=SUMPRODUCT((holidays>=start)*(holidays<=end))
Zusammenfassung
Um Feiertage zu zählen, die zwischen zwei Daten liegen, können Sie die Funktion SUMPRODUCT verwenden.
In dem gezeigten Beispiel lautet die Formel in F8:
=SUMPRODUCT((B4:B12>=F5)*(B4:B12<=F6))
Erläuterung
Diese Formel verwendet zwei Ausdrücke in einem einzelnen Array innerhalb der SUMPRODUCT-Funktion.
Der erste Ausdruck testet jedes Feiertagsdatum, um festzustellen, ob es größer oder gleich dem Startdatum in F5 ist:
(B4:B12>=F5)
Dies gibt ein Array von TRUE / FALSE-Werten wie folgt zurück:
(FALSE; FALSE; FALSE; FALSE; TRUE; TRUE; TRUE; TRUE; TRUE)
Der zweite Ausdruck testet jedes Feiertagsdatum, um festzustellen, ob es kleiner oder gleich dem Enddatum in F6 ist:
(B4:B12<=F6)
Dies gibt ein Array von TRUE / FALSE-Werten wie folgt zurück:
(WAHR; WAHR; WAHR; WAHR; WAHR; WAHR; WAHR; WAHR; FALSCH)
Die Multiplikation dieser beiden Arrays zwingt die TRUE / FALSE-Werte automatisch zu Einsen und Nullen, was zu Arrays führt, die folgendermaßen aussehen:
=SUMPRODUCT(((0;0;0;0;1;1;1;1;1))*((1;1;1;1;1;1;1;1;0)))
Nach der Multiplikation haben wir nur ein Array wie dieses:
=SUMPRODUCT((0;0;0;0;1;1;1;1;0))
Schließlich summiert SUMPRODUCT die Elemente im Array und gibt 4 zurück.
Feiertage nur an Wochentagen
Um Feiertage zu zählen, die nur an Wochentagen (Mo-Fr) auftreten, können Sie die Formel folgendermaßen erweitern:
=SUMPRODUCT((rng>=F5)*(rng<=F6)*(WEEKDAY(rng,2)<6))
Dabei ist rng ein Bereich, der Feiertagsdaten enthält.
